Elektronik 2 PSPICE Elemente Seite A-1 Beschreibung

Elektronik 2
PSPICE Elemente
Seite
A-1
Beschreibung der SPICE-Elemente
Das Analog-Simulationsprogramm SPICE orientiert sich sehr wesentlich am ersten Zeichen einer Eingabe-Zeile.
Übersicht über die Bedeutung des ersten Zeichens in einer Zeile
*
Kommentarzeile
+
Fortsetzungszeiel
.
Beginn einer Modellanweisung
In einer Zeile wird der Text nach ';' als Kommentar interpretiert.
Beispiel:
* Beispiel einer Kommentarzeile
.model BC182 NPN(Is=12.03f Xti=3 Eg=1.11 Vaf=37.37 Bf=290
+Ne=1.971 Ise=2.732p Ikf=.1072 Xtb=1.5 Br=4.379 Nc=2
+Isc=0 Ikr=0 Rc=2.5 Re=1.5 Cjc=5.777p Mjc=.3199
+Vjc=.75 Fc=.5 Cje=8.307p Mje=.384 Vje=.75
+Tr=698.4p Tf=385.4p Itf=.17 Vtf=3 Xtf=8 Rb=10)
* National pid=04 case=TO92 26.12.92 P. Raemy
.PROBE ; wichtig zur grafischen Darstellung
In Standard-SPICE sind nur die folgenden Zeichen erlaubt:
Grossbuchstaben (ohne Ä Ö Ü)
Zahlen 0..9 und
-
. () = +
PSPICE behandelt Kleinbuchstaben wie grosse. Nach dem Kennbuchstaben können noch weitere 7 Zeichen zur Unterscheidung folgen.
In den folgenden Erläuterungen werden Angaben, die optional sind, in eckige
Klammern gesetzt.
Die Angabe
[IC=Io]
bedeutet, dass die Angabe IC= gefolgt von einem Wert I o nicht zwingend notwendig ist.
Elektronik 2
PSPICE Elemente
Seite
A-2
Passive Elemente
Elementanweisung des Widerstandes
Rname Knotena Knotenb Wert [TC=α [,ß]]
Wo α für den linearen und ß für den quadratischen Temperaturkoeffizient angegeben werden kann. Der Widerstandwert ist damit wie folgt von der Temperatur
abhängig:
R T = R o (1 + α ΔT + ß ΔT 2 )
avec
ΔT = T - T o
T o ist die Temperatur, mit der die Schaltung simuliert wird. Diese ist
normalerweise 27°, resp. 300.15 K. Andere Temperaturen können mit
der Anweisung TNOM unter .OPTION gesetzt werden. Mit der Anweisung .TEMP kann das Verhalten der Schaltung bei weitern Temperaturen simuliert werden.
Beispiel: Anweisung zur Simulation eines Thermosensors Pt 100 zwischen den Knoten 10
und 11 mit α = 3.9 10 -3 /K und ß= -0.58 10 -6 /K 2
RPT100 10 11 105.09 TC=3.9E-3,-0.58E-6
Ein spannungsabhängiger Widerstand (VDR) kann mit einer spannungsgesteuerten Stromquelle realisiert werden (siehe unter dem Kennbuchstaben G).
Elementanweisung des Kondensators
Cname Knotena Knotenb Wert [IC=Uo]
Beispiel: Bei einer Transientenanalyse (.TRAN) soll der Kondensator CELKO
(100 µF) zwischen den Knoten 21 und 22 zu Beginn mit einer Spannung von 10V geladen sein. IC definiert hier den Anfangswert. Damit
mit dem spezifizierten Anfangswert gerechnet wir, muss in der Zeile
mit der .TRAN Anweisung UIC (Use Initial Condition) stehen.
CELKO 21 22 100u IC=10
.TRAN 0.1m 5m UIC
An Stelle eines fixen Kapazitätswertes kann mit der Angabe POLY 1 und nachfolgenden Koeffizienten ein Polynom C n (U) n-ten Grades eingegeben werden.
C n (U) = C o + C 1 U + C 2 U 2 + ... + C n U n
1
In PSPICE wir an Stelle der Poly-Anweisung die Verwendung VALUE oder TABLE empfohlen.
Elektronik 2
PSPICE Elemente
Seite
A-3
Beispiel:
CELKO 21 22 POLY(1) 100u 0 -10n IC=10
entspricht folgender Beziehung
C(U) = 100 uF + 0 - 10 . 10 -9 F/V 2 . U 2
Elementanweisung der Induktivität
Lnane Knotena Knotenb Wert [IC=Io]
Es gelten dieselben Hinweise wie beim Kondensator ausser, dass hier als Anfangsbedingung ein Strom I o angegeben werden kann. Ebenso kann mit der Angabe POLY ein Polynom L n (I) definiert werden.
L n (I) = L o + L 1 I + L 2 I 2 + ...+ L n I n
Damit kann beispielsweise die Sättigung im Eisenkern einer Drossel berücksichtigt werden.
Elektronik 2
PSPICE Elemente
Seite
A-4
Quellen
Spannungquelle
Vname Knotena Knotenb Kurvenform Wert
Bei einem positiven Wert liegt der Plusspol am Knoten a.
Stromquelle
Iname Knotena Kontenb Kurvenform Wert
Ein positiver Strom fliesst in den Knoten a.
Forme de signal:
DC-Quelle
[DC] [Wert]
AC-Quelle
AC [Ap [Phase]]
Nur zur .AC Analyse. Die Frequenz wird in der .AC-Anweisung eingegeben.
Puls Quelle
PULSE(Ao Ap [td [tr [tf [tw [T]]]]])
Sinus Quelle
SIN(Ao Ap [f [td [alpha]]])
0 ≤ t ≤ t d : a(t) = A o
td ≤ t
: a(t) = A o + A p sin(2π f(t-t d )) e -alph a(t-td )
weiter gibt es noch:
Exponentialquelle
EXP
Polygonquelle
PWL
Frequenzmodulierte Quelle
SFFM
Elektronik 2
PSPICE Elemente
Seite
A-5
Gesteuerte Quellen
Spannungsgesteuerte Stromquelle
Gname a+ a- e+ e- y
Spannungsgesteuerte Spannungsquelle
Ename a+ a- e+ e- v
Stromgesteuerte Stromquelle
Diese Quelle wird durch zwei Anweisungen definiert.
Fname a+ a- Vname v
Vname e+ e-
Stromgesteuerte Spannungsquelle
Diese Quelle wird durch zwei Anweisungen definiert.
Hname a+ a- Vname z
Vname e+ e-
Bei gesteuerten Quellen besteht noch die Möglichkeit, an Stelle der linearen Beziehung zwischen den Ein- und Ausgangsgrössen ein Polynom anzugeben.
Elektronik 2
PSPICE Elemente
Anweisung für die Analyseart
Frequenzanalyse
lineare Frequenzachse
.AC LIN anz_Punkte fstart fstop
logarithmische Achse
.AC DEC Punkte_pro_Dekade fstart fstop
logarithmische Achse
.AC OCT Punkte_pro_Oktave fstart fstop
Transientenanalyse
.TRAN tstep tstop [tstart [max_step]] [UIC]
Temperaturanalyse
.TEMP T1 [ T2 [ T3 [ etc. ]]]
DC-Analyse
.DC quellenbez start stop step [quellenbez start stop step]
weitere Analysearten:
DC-Arbeitspunkt
.OP
Tranferanalyse
.TF
Empfindlichkeitanalyse
.SENS
Kennlinie
.DC
Klirrfaktoranalyse
.DISTO 2
Fourieranalyse
.FOUR
Rauschanalyse
.NOISE
Monte Carlo Analyse
.MC
2
.DISTO wird von PSPICE nicht unterstützt.
Seite
A-6
Elektronik 2
PSPICE Elemente
Seite
A-7
Halbleitermodelle
Diode
Dname kn p kn n model_name [Fläche] [OFF] [IC=Uo]
.MODEL model_name D(IS=.. RS=.. etc.)
Beachte: Pro Diodentyp ist nur eine einzige .MODEL – Anweisung erforderlich.
Die folgenden 14 Parameter können in der .MODEL –Anweisung spezifiziert
werden:
Nr. Bez.
Parameter
Default
Fläche
1
IS
Sperrsättigungsstrom I S in A
10 - 1 4
*
2
RS
Bahnwiderstand R B in Ohm
0
*
3
N
Emissionskoeffizient m
1
4
TT
Minoritätsträgerlebensdauer τ
in s
0
5
CJ0
Null-Sperrschichtkapazität C j 0 in F
0
6
VJ
Diffusionsspannung U D in V
1
7
M
Exponent von C j 0
0.5
8
EG
Bandabstand E G in eV
1.11.
9
XTI
Temperexponent von I S
3
10
KF
Funkelrauschkoeffiezient ’Flicker-noise’ k F
0
11
AF
Funkelrauschexponent ’Flicker-noise’ a F
1
12
FC
C j Koeffiezient im Durchlassbereich f C
0.5
13
BV
Sperrdurchbruchspannung U R B in V
infini
14
IBV
Strom bei U R B in A
10 - 3
Beispiel:
D1 4 5 DIODE
D2 5 6 DIODE
.MODEL DIODE D
* verwendet Ersatzwert insbesondere RS=0
*
Elektronik 2
Bipolartransistor
PSPICE Elemente
Seite
A-8
Qname c b e [substr] model_name [Fläche] [OFF] [IC=U BE ,UCE]
.MODEL model_name NPN(IS=.. BF=.. NF=.. etc.)
oder
.MODEL model_name PNP(IS=.. BF=.. NF=.. etc.)
Elektronik 2
PSPICE Elemente
Seite
A-9
Bibliothek
In Bibliotheken finden wir die Modell-Angaben von vielen Bauteilen bereits vordefiniert. Inzwischen gibt es von einigen Firmen SPICE-Modelle ihrer Halbleiterbauteile. So z.B. gibt es von
MOTOROLA
Modelle ihrer Transistoren
und von
TEXAS INSTRUMENTS,
Analog Device, etc.
NATIONAL
SEMICONDUCTOR,
PMI,
die Modelle von Operationsverstärkern und anderen linearen Elementen.
Der bekannte Operationsverstärker 741 besteht aus mehr als 20 Transistoren und
könnte deshalb nicht mehr mit der PSPICE Demoversion simuliert werden. Zudem würde die Simulationszeit recht gross. Aus diesem Grunde sind in den Bibliotheken sogenannte Makromodelle enthalten, in welchen normalerweise nur
die Eingangs- und gelegentlich die Ausgangstransistoren vorhanden sind. Die eigentlichen Funktionen werden mit gesteuerten Quellen nachgebildet.
Die Bibliothek der Demoversion heisst NOM.LIB (resp. EVAL.LIB für die Version 5.1). Der Operationsverstärker µA 741 ist darin wie folgt definiert:
* connections: non-inverting input
*
| inverting input
*
| | positive power supply
*
| | | negative power supply
*
| | | | output
*
| | | | |
.subckt uA741 1 2 3 4 5
c1 11 12 8.661E-12
c2 6 7 30.00E-12
dc 5 53 dx
de 54 5 dx
dlp 90 91 dx
dln 92 90 dx
dp 4 3 dx
egnd 99 0 poly(2) (3,0) (4,0) 0 .5 .5
fb 7 99 poly(5) vb vc ve vlp vln 0 10.61E6 -10E6 10E6 10E6 -10E6
ga 6 0 11 12 188.5E-6
gcm 0 6 10 99 5.961E-9
iee 10 4 dc 15.16E-6
hlim 90 0 vlim 1K
q1 11 2 13 qx
q2 12 1 14 qx
r2 6 9 100.0E3
rc1 3 11 5.305E3
rc2 3 12 5.305E3
re1 13 10 1.836E3
re2 14 10 1.836E3
ree 10 99 13.19E6
ro1 8 5 50
ro2 7 99 100
rp 3 4 18.16E3
vb 9 0 dc 0
vc 3 53 dc 1
ve 54 4 dc 1
vlim 7 8 dc 0
Elektronik 2
PSPICE Elemente
Seite
vlp 91 0 dc 40
vln 0 92 dc 40
.model dx D(Is=800.0E-18 Rs=1)
.model qx NPN(Is=800.0E-18 Bf=93.75)
.ends
In einer Netzliste wird ein Bauteil au seiner Bibliothek wie folgt aufgerufen:
Xnom kn1 kn2 . . . knn subct_name [Parameter]
.LIB G:\UTIL\PSPICE\NOM.LIB
Beispiel:
VP 12 0 DC 15
VN 11 0 DC -15
.
.
X1 0 2 12 11 5 uA741
.LIB G:\UTIL\PSPICE\NOM.LIB
A-10